*****************************RCA12AX7A Spice Model "Dream" Version 3.0 (Pspice sintax)**************************************            
*************************created by Leonardo Di Carlo on 20th January 2008************************                             
*$
.SUBCKT 12AX7A 1 2 3                                                                                                        
*              A G C                                                                                                        
+PARAMS: CCG=2.3P  CGP=2.4P CCP=.9P  D1=0.18 K1=0.95 Voff=-0.74 h=0.6 Isat=8e-3 SF=0.7
*
E1 100 0 Value={IF(V(2,3)<-5,-5,IF(V(2,3)>=-5&V(2,3)<0,V(2,3),0))};
*
GG 11 0 POLY(1) (100,0) 0.001101619007573 1.512376135073021e-005 -3.155955520344564e-005 -3.286231900854539e-006
VG 12 11 0
RG 12 0 1P
*
GMU 15 0 POLY(1) (100,0) 99.704829344364796 -0.022980852114950 -0.448893261889592 -0.022265711331488
VMU 16 15 0
RMU 16 0 1P
*
GSpacefrac 17 0 Value={(I(VG)*(PWR(V(2,3)+h+V(1,3)/I(VMU),1.5)+PWRS(V(2,3)+h+V(1,3)/I(VMU),1.5))/2)/Isat} 
VSpacefrac 18 17 0 
RSpacefrac 18 0 1P
*
Gspace 31 0 Value={IF(I(VSpacefrac)<SF,I(VSpacefrac)*Isat,(SF+((I(VSpacefrac)-SF)*(1-SF))/(1-2*SF+I(VSpacefrac)))*Isat)}
Vspace 32 31 0
Rspace 32 0 1P
*
Ggrid1 20 0 Value={IF(V(2,3)>=Voff,I(VSpace)/(1+D1*(V(1,3)/(V(2,3)+(-Voff)))**K1),0)} 
Vgrid1 21 20 0   
Rgrid1 21 0 1P                                                                    
GPlate1 22 0 Value={I(Vspace)-I(Vgrid1)}                                   
VPlate1 23 22 0                                                          
RPlate1 23 0 1P
*
FPlate 1 3 VPlate1 1 
FGrid 2 3 Vgrid1 1
C1 2 3 {CCG}                                                                          
C2 2 1 {CGP}                                                                          
C3 1 3 {CCP}                                                                          
.ENDS